(import scheme
        (chicken base)
        (chicken process-context)
        (only srfi-197 chain)
        (prefix sdl2 "sdl2:")
        (prefix sdl2-ttf "ttf:")
        (prefix sdl2-image "img:")
        downstroke-engine
        downstroke-world
        downstroke-tilemap
        downstroke-renderer
        downstroke-input
        downstroke-physics
        downstroke-assets
        downstroke-entity
        downstroke-sound
        downstroke-scene-loader)

(define +debug?+ (and (member "--debug" (command-line-arguments)) #t))

(define (make-player)
  (list #:type 'player
        #:x 100 #:y 50
        #:width 16 #:height 16
        #:vx 0 #:vy 0
        #:gravity? #t #:on-ground? #f
        #:tile-id 1 #:tags '(player)))

(define (player-vx input)
  (cond ((input-held? input 'left)  -3)
        ((input-held? input 'right)  3)
        (else 0)))

(define (update-player player input tm)
  (let ((jump? (input-pressed? input 'a)))
    (when (and jump? (entity-ref player #:on-ground? #f))
      (play-sound 'jump))
    (chain (entity-set player #:vx (player-vx input))
           (apply-jump _ jump?)
           (apply-acceleration _)
           (apply-gravity _)
           (apply-velocity-x _)
           (resolve-tile-collisions-x _ tm)
           (apply-velocity-y _)
           (resolve-tile-collisions-y _ tm)
           (detect-on-solid _ tm))))

(define *game*
  (make-game
    title: "Demo: Platformer" width: 600 height: 400
    debug?: +debug?+

    preload: (lambda (game)
      (init-audio!)
      (load-sounds! '((jump . "demo/assets/jump.wav"))))

    create: (lambda (game)
      (game-scene-set! game
        (chain (game-load-scene! game "demo/assets/level-0.tmx")
          (scene-add-entity _ (make-player))
          (update-scene _ camera-target: 'player))))

    update: (lambda (game dt)
      (let* ((input  (game-input game))
             (scene  (game-scene game))
             (tm     (scene-tilemap scene))
             (player (update-player (car (scene-entities scene)) input tm)))
        (game-scene-set! game
          (update-scene scene entities: (list player)))))))

(game-run! *game*)